HTTPS для OpenServer (SSL сертификат)

Реально работает инструкция отсюда – https://wp-kama.ru/note/ssl-openserver#2-zapuskaem-fajl-generate-dom-cert-bat

коротенько

Нужно создать – C:\OpenServer\userdata\config\cert_files\generate-DOM-CERT.bat

: Version 1.0
: Author unknown (improved by Kama - wp-kama.ru)
@echo off

: parameters

set DOM=demo.ru
set DOM_KEY=demo
set APACHE_VER=Apache_2.4-PHP_7.2-7.3-x64

: create .txt config file
set config_txt=generate-temp-config.txt
(
	echo nsComment = "Open Server Panel Generated Certificate"
	echo basicConstraints = CA:false
	echo subjectKeyIdentifier = hash
	echo authorityKeyIdentifier = keyid,issuer
	echo keyUsage = nonRepudiation, digitalSignature, keyEncipherment
	echo.
	echo subjectAltName = @alt_names
	echo [alt_names]
	echo DNS.1 = %DOM%
	echo DNS.2 = www.%DOM%
) > %config_txt%

mkdir %DOM_KEY%

set OSAPACHE_DIR=%~dp0..\..\..\modules\http\%APACHE_VER%
set OPENSSL_CONF=%OSAPACHE_DIR%\conf\openssl.cnf
"%OSAPACHE_DIR%\bin\openssl" req -x509 -sha256 -newkey rsa:2048 -nodes -days 5475 -keyout %DOM_KEY%\%DOM_KEY%-rootCA.key -out %DOM_KEY%\%DOM_KEY%-rootCA.crt -subj /CN=OSPanel-%DOM_KEY%/
"%OSAPACHE_DIR%\bin\openssl" req -newkey rsa:2048 -nodes -days 5475 -keyout %DOM_KEY%/%DOM_KEY%-server.key -out %DOM_KEY%\%DOM_KEY%-server.csr -subj /CN=%DOM_KEY%/
"%OSAPACHE_DIR%\bin\openssl" x509 -req -sha256 -days 5475 -in %DOM_KEY%\%DOM_KEY%-server.csr -extfile %config_txt% -CA %DOM_KEY%\%DOM_KEY%-rootCA.crt -CAkey %DOM_KEY%\%DOM_KEY%-rootCA.key -CAcreateserial -out %DOM_KEY%\%DOM_KEY%-server.crt
"%OSAPACHE_DIR%\bin\openssl" dhparam -out %DOM_KEY%\%DOM_KEY%-dhparam.pem 2048

del %DOM_KEY%\%DOM_KEY%-server.csr
del %DOM_KEY%\%DOM_KEY%-dhparam.pem
del %DOM_KEY%\%DOM_KEY%-rootCA.srl
del %config_txt%

pause

Редактируем файл - подставляем свои данные

set DOM=crovatti.ru
set DOM_KEY=crovatti
set APACHE_VER=Apache_2.4-PHP_7.2-7.4

После того как он отработает будут созданы файлы сертификата -

w:\OSPanel-5.3.7\userdata\config\cert_files\crovatti\
crovatti-rootCA.crt
crovatti-server.crt
crovatti-rootCA.key
crovatti-server.key

Регистрируем (просто запускаем) в Windows crovatti-rootCA.crt

Копируем актуальный файл конфигурации сервера (версию посмотреть в настройках OSPanel, вкладка Модули, HTTP) в корневую папку сайта (там где wp-config.php)

w:\OSPanel-5.3.7\userdata\config\Apache_2.4-PHP_7.2-7.4_ vhost .conf

Исправляем 2 строчки в этом файле (пути и имена -server.crt и -server.key ) в локальной папке сайта

SSLCertificateFile "%sprogdir%/userdata/config/cert_files/crovatti/crovatti-server.crt"

SSLCertificateKeyFile "%sprogdir%/userdata/config/cert_files/crovatti/crovatti-server.key"

Это все!

Не забыть перезагрузить OpenServer и возможно браузер.

Должно работать. У меня заработало.

А зачем все эти мученья?
А вот, например, зачем - бот будет отправлять вам сообщения, только в случае, если у вас есть SSL сертификат. Не говоря уже о том что при переносе сайта с локального компьютера на хостинг должны соответствовать ссылки с префиксом https.

Поделиться с друзьями